hitexroid

آموزش کار با Hitex_RecyclerViewPager

4 ارسال در این موضوع قرار دارد

مثال ساده اول : 

Sub Globals
	Dim RVP As Hitex_RecyclerViewPager
End Sub

Sub Activity_Create(FirstTime As Boolean)
	RVP.Initialize("RVP")
	Activity.AddView(RVP,0,0,100%x,100%y)

	RVP.Orientation = RVP.HORIZONTAL
	RVP.SinglePageFling = True
	RVP.Show
End Sub

Sub RVP_onCreateViewHolder (Parent As Panel, ViewType As Int)      '💎 onCreate 💎'
	Dim lbl As Label : lbl.Initialize("lbl")
	lbl.Gravity = Gravity.CENTER
	Parent.AddView(lbl,0,0,100%x,100%y)
	
	Parent.Color = Colors.RGB(Rnd(0,256),Rnd(0,256),Rnd(0,256))
End Sub

Sub RVP_onBindViewHolder (Parent As Panel, Position As Int)         '💠 onBind 💠'
	Dim lbl = Parent.GetView(0) As Label
	lbl.Text = "Text " & Position
End Sub

Sub RVP_GetItemCount As Int 								        '💯 ItemCount 💯'
 	Return 10 '/ItemList.Size
End Sub

 

مثال پیشرفته دوم : 

Sub Process_Globals
	Public TYPE_IMAGE = 0, TYPE_TEXT = 1, TYPE_BUTTON = 2 As Int
End Sub

Sub Globals
	Dim RVP As Hitex_RecyclerViewPager
	Type Layout(ViewType As Int, Text As String)
	Dim ItemList As List
End Sub

Sub Activity_Create(FirstTime As Boolean)
	RVP.Initialize("RVP")
	Activity.AddView(RVP,0,0,100%x,100%y)
	
	ItemList.Initialize
	
	RVP.Orientation = RVP.HORIZONTAL
	RVP.SinglePageFling = True
	RVP.Show
	
	AddNewPage(TYPE_IMAGE, "smart1.jpg")
	AddNewPage(TYPE_TEXT, "Hitex Recycler View")
	AddNewPage(TYPE_BUTTON, "GOTO Page 1")
End Sub

Sub RVP_onCreateViewHolder (Parent As Panel, ViewType As Int)      '💎 onCreate 💎'
	
	Select (ViewType)
		Case TYPE_IMAGE :
			Dim img As ImageView : img.Initialize("img")
			img.Gravity = Gravity.FILL
			Parent.AddView(img,0,0,100%x,100%y)
		Case TYPE_TEXT :
			Dim lbl As Label : lbl.Initialize("lbl")
			lbl.Gravity = Gravity.CENTER : lbl.TextSize = 22
			lbl.Typeface = Typeface.DEFAULT_BOLD
			Parent.AddView(lbl,0,0,100%x,100%y)
			Parent.Color = Colors.RGB(Rnd(0,256),Rnd(0,256),Rnd(0,256))
		Case TYPE_BUTTON :
			Dim btn As Button : btn.Initialize("btn")
			btn.Gravity = Gravity.CENTER
			Parent.AddView(btn,10%x,30%y,80%x,30%y)
			Parent.Color = Colors.RGB(Rnd(0,256),Rnd(0,256),Rnd(0,256))
	End Select
End Sub

Sub RVP_onBindViewHolder (Parent As Panel, Position As Int)         '💠 onBind 💠'
		
		Dim Item = ItemList.Get(Position) As Layout
		
		Select (Item.ViewType)
			Case TYPE_IMAGE :
				Dim img = Parent.GetView(0) As ImageView
				img.Bitmap = LoadBitmap(File.DirAssets,Item.Text)
			Case TYPE_TEXT :
				Dim lbl = Parent.GetView(0) As Label
				lbl.Text = Item.Text
			Case TYPE_BUTTON :
				Dim btn = Parent.GetView(0) As Button
				btn.Text = Item.Text
		End Select
		
End Sub

Sub RVP_GetItemCount As Int 								        '💯 ItemCount 💯'
 	Return ItemList.Size
End Sub

Sub RVP_GetItemViewType (Position As Int) As Int				   '🎭 GetItemViewType 🎭'
	Dim Item = ItemList.Get(Position) As Layout
	Return Item.ViewType
End Sub

Sub AddNewPage (ViewType As Int, Text As String)
	Dim Item As Layout
	Item.ViewType = ViewType
	Item.Text = Text
	ItemList.Add(Item)
	RVP.notifyItemAdded
End Sub

Sub btn_Click
	RVP.GotoPage(0,True)
End Sub

 

به اشتراک گذاری این ارسال


لینک به ارسال
به اشتراک گذاری در سایت های دیگر

با سلام 

من مثل همین کد ها رو نوشتم وساب 

Sub RVP_GetItemCount As Int 								        '💯 ItemCount 💯'
 	Return ItemList.Size
End Sub

رو هم گذاشتم اما موقعی که فایل رو اجرا میکنم ویو پیجر نمیاد و ارور میده و قسمت لاگ ها مینویسه این ساب رو فراموش کردید

java.lang.IllegalStateException: You forgot to create Sub 'ViewPger_GetItemCount'

ممنون میشم راهنمایی کنید

 

به اشتراک گذاری این ارسال


لینک به ارسال
به اشتراک گذاری در سایت های دیگر

طبق این ارور

java.lang.IllegalStateException: You forgot to create Sub 'ViewPger_GetItemCount'


نوشتید ViewPger و یه a کم گذاشتید و به احتمال خیلی زیاد توی Initialize کامل نوشتید Pager رو

به همین دلیل ٬ ساب رو نمیشناسه و ارور میده

 

ویرایش شده در توسط sajjad80

به اشتراک گذاری این ارسال


لینک به ارسال
به اشتراک گذاری در سایت های دیگر

برای ارسال دیدگاه یک حساب کاربری ایجاد کنید یا وارد حساب خود شوید

برای اینکه بتوانید دیدگاهی ارسال کنید نیاز دارید که کاربر سایت شوید

ایجاد یک حساب کاربری

برای حساب کاربری جدید در سایت ما ثبت نام کنید. عضویت خیلی ساده است !

ثبت نام یک حساب کاربری جدید

ورود به حساب کاربری

دارای حساب کاربری هستید؟ از اینجا وارد شوید

ورود به حساب کاربری